on *:start: { 
  timerupdatetitle -o 0 1 updatetitle
  newday
  fullname http://joshuacasey.net
  mnick Joshua
  .timestamp -f [yyyy-mm-dd HH:nn:ss]
}

alias updatetitle {
  titlebar $chr(151) $+ $chr(155) $asctime(dddd) $+ $chr(44) $asctime(mmmm ddoo) $+ $chr(44) $asctime(yyyy) $chr(149) $asctime(HH:nn:ss zzz)
  ;  titlebar $chr(151) $+ $chr(155) $day $+ $chr(44) $date(mmmm) $date(dd) $+ $chr(44) $date(yyyy) $chr(151) $time(hh:nn:ss tt) $chr(40) $+ GMT: $time(zz) $+ $chr(41)
  ;It is $time(HH:mm:ss) GMT $time(ZZ) on $day $chr(07)
}

alias newday { timer -o 00:00 1 0 /print_newday }
alias print_newday {
  aline -ap @whois 14** $+($time(dddd),$chr(44),$chr(32),$time(mmmm),$chr(32),$time(dd),$chr(44),$chr(32),$time(yyyy),$chr(32),$time(HH:nn:ss)) **
  aline -ap @awaylog 14** $+($time(dddd),$chr(44),$chr(32),$time(mmmm),$chr(32),$time(dd),$chr(44),$chr(32),$time(yyyy),$chr(32),$time(HH:nn:ss)) **
  ;  aline -ap @notice.SwiftIRC 14** $+($time(dddd),$chr(44),$chr(32),$time(mmmm),$chr(32),$time(dd),$chr(44),$chr(32),$time(yyyy),$chr(32),$time(HH:nn:ss)) **
}

on *:connect: {
  $iif($ini(connect.ini,$network,Nick),nick $readini(connect.ini,n,$network,Nick))
  $iif($network == Quakenet,auth $readini(connect.ini,n,$network,Nick) $decode($readini(connect.ini,n,$network,Pass),m),quote nickserv identify $decode($readini(connect.ini,n,$network,Pass),m))

  ;Oper Login for users that may have Oper permissions on a network
  $iif($readini(connect.ini,n,$network,Oper) == Yes,oper $readini(connect.ini,n,$network,Ousername) $decode($readini(connect.ini,n,$network,Opass),m))

  $iif($readini(connect.ini,n,$network,Modes),mode $me $readini(connect.ini,n,$network,Modes))
}

on ^*:NOTICE:Password accepted - you are now recognized*:?: {
  if ($nick == NickServ) {
    var %channeltotal $gettok($readini(connect.ini,n,$network,Channels),0,44)
    join -x $gettok($readini(connect.ini,n,$network,Channels),1- %channeltotal,44)
  }
}
on ^*:NOTICE:You are now identified for*:?: {
  if ($nick == NickServ) {
    var %channeltotal $gettok($readini(connect.ini,n,$network,Channels),0,44)
    join -x $gettok($readini(connect.ini,n,$network,Channels),1- %channeltotal,44)
  }
}
raw 396:*hidden host*: {
  join -x $readini(connect.ini,n,$network,Channels)
}

alias network {
  if ($1 == addnick) {
    .remini -n connect.ini $network Nick
    .writeini -n connect.ini $network Nick $2
    echo 14 -g Added $2 to $network
  }
  elseif ($1 == addpass) {
    .remini -n connect.ini $network Pass
    .writeini -n connect.ini $network Pass $encode($2,m)
    echo 14 -g Added $encode($2,m) to $network
  }
  elseif ($1 == addmodes) {
    .remini -n connect.ini $network Modes
    .writeini -n connect.ini $network Modes $+(+,$remove($2,+))
    echo 14 -g Added $+(+,$2) to $network
  }
  elseif ($1 == addoper) {
    .writeini -n connect.ini $network Oper yes
    .writeini -n connect.ini $network Ousername $2
    .writeini -n connect.ini $network Opass $encode($3,m)
    echo 14 -g Added $2 and $encode($3,m) to $network
  }
  elseif ($1 == addchan) {
    .writeini -n connect.ini $network Channels $addtok($readini(connect.ini,n,$network,Channels),$2,44)
    echo 14 -g Added $2 to $network
  }
  elseif ($1 == delchan) {
    .writeini -n connect.ini $network Channels $remtok($readini(connect.ini,n,$network,Channels),$2,44)
    echo 14 -g Removed $2 from $network
  }
  else {
    echo 14 -g Usage: /network addnick Nick
    echo 14 -g Usage: /network addpass Pass
    echo 14 -g Usage: /network addmodes Modes
    echo 14 -g Usage: /network addchan Channel1,Channel2,Channel3
    echo 14 -g Usage: /network delchan channel
    echo 14 -g Usage: /network addoper opername operpass
  }
}

; Automatically identifies you if needed (if the nickname belongs to you
; On the specified network (requires settings in connect.ini) (USE /network alias from above)
on ^*:NOTICE:*This nickname is registered and protected. If it is your*:?: {
  if ($me == $readini(connect.ini,$network,Nick)) {
    quote nickserv identify $decode($readini(connect.ini,n,$network,Pass),m)
  }
}
on ^*:NOTICE:You have 30 seconds to identify to your nickname before it is changed.:?: {
  if ($nick == NickServ) {
    quote nickserv identify $decode($readini(connect.ini,n,$network,Pass),m)
  }
}

; If nickname is already in use, and belongs to us (specified in connect.ini)
; Ghost the nickname, switch to it, and identify
raw 433:*is already in use.: {
  if ($2 == $readini(connect.ini,$network,Nick)) {
    ;quote nickserv ghost $2 $decode($readini(connect.ini,n,$network,Pass),m)
    nick $2
    quote nickserv identify $decode($readini(connect.ini,n,$network,Pass),m)
  }
}